change multiple renderpasses quicker

A script for changing quick and easy Attributes of multiple Passes in 3delight.
Changing the Attrs for 3deligth could be a little bit slow, because of the Ui refresh for every attr change.

With the script is possible to change the Attrs for all selected Passes with only one Ui refresh.

Put both Script in your "C:\Documents and Settings\user\My Documents\maya\version-x64 or -x86\scripts"
and start with typing "rf_m3dl_UI" in the commandLine .



The script is also nice to be proof that motionblur is on or that the animation Attr is on, before you render your scene.

Quality and MotionBlur Attrs could be change with a RMB click on the Attr Name.



download:
http://dl.dropbox.com/u/34893475/rf_m3dl_procs.mel
http://dl.dropbox.com/u/34893475/rf_m3dl_UI.mel

// CODE UI


global proc rf_m3dl_UI() {

    string $delightPasses[] = `ls -type "delightRenderPass" `;
    int $delightPassesIndex =` size($delightPasses)` ;
    string $listCams[] =`ls -type "camera"` ;
    source rf_m3dl_procs ;

    if ( `window -exists multPassWindow` ) {
     deleteUI multPassWindow;
     }

    ////////////////////////////////////////////////////////////////////////////////
    //UI
    ///////////////////////////////////////////////////////////////////////////////

    window -height 300 -title "changeMulti_3delightPasses" -width 300 -mb true -rtf true multPassWindow ;
        columnLayout -columnWidth 204 -height 300 -width 300;
            text -height 30 -label "select delightRenderPasses" -width 300;
            textScrollList -height 93 -width 340 -ams true passesTSL ;
            separator -height 17 -width 340;
            button -height 32 -label "refresh passes" -c "refreshTL" -width 340;
           
    
           
            frameLayout -label "Camera " -collapsable true -cl true -borderStyle "etchedIn" -mw 30 -w  340 -bgc 0.24 0.24 0.24 ;
                separator -height 17 -width 340;
                optionMenu -label "Camera" -width 240 -h 28 camOM ;
                                menuItem -label "keep current Camera" ;
                                for ($currentCam in $listCams){
                                 menuItem -label $currentCam ;
                                }
                separator -height 17 -width 340;
                optionMenu -label "Animation" -width 240 -h 28 animOM ;
                    menuItem -label  "keep current Settings" ;
                    menuItem -label  "Animation On" ;
                    menuItem -label  "Animation Off" ;
           
                checkBox -onCommand "aniFrameONproc" -offCommand "aniFrameOFFproc" -label "set a new frameRange " -height 14  -width 300 -en true snFRCB ;                
                rowLayout
                    -numberOfColumns 4 ;
                 
                        text -label "startFrame" -w 60 -h 20 -en false startFrameTXT ;
                        intField -w 75 -h 20 -v 1 -en false startFrameIF ;
                        intField -w 75 -h 20 -v 1 -en false endFrameIF ;
                        text -label "endFrame" -w 60 -h 20 -en false endFrameTXT;
                     setParent ..;        
                separator -height 17 -width 340;
                optionMenu -label "Use Imager Shaders" -width 240 -h 28 uISOM ;
                    menuItem -label  "keep current Settings" ;
                    menuItem -label  "on" ;
                    menuItem -label  "off" ;
               
               
            setParent ..;
            //Output FrameLayout
            frameLayout -label "Output " -collapsable true -cl true -borderStyle "etchedIn" -mw 30 -w  340 -bgc 0.24 0.24 0.24 ;
                    optionMenu -label "Render mode" -width 240 -h 28 rmOM ;
                    menuItem -label  "keep current Settings" ;
                    menuItem -label  "Render" ;
                    menuItem -label  "Save RIB" ;
                    menuItem -label  "RIB Archive" ;
                    menuItem -label  "Background Render" ;
           
               
            setParent ..;
           
            //Quality FrameLayout
           
            frameLayout -label "Quality" -collapsable true -cl true -borderStyle "etchedIn" -mw 30 -w  340 -bgc 0.24 0.24 0.24 ;
                        rowLayout
                        -numberOfColumns 2
                        -columnWidth2 45 120
                        -columnAlign2 "left" "left" ;
                            text -label "ShadingRate" -w 120 -h 20;
                                popupMenu;
                                    menuItem -label "keep current Values" -c "shadingRateOffFF" ;
                                    menuItem -label "enable Values" -c "shadingRateOnFF" ;
                            floatField -w 150 -h 20 -v 1 -en false srFF ;
                        setParent ..;
                        rowLayout
                        -numberOfColumns 2
                        -columnWidth2 45 120
                        -columnAlign2 "left" "left" ;
                            text -label "Raytrace Max Depth" -w 120 -h 20;
                                popupMenu;
                                    menuItem -label "keep current Values" -c "raytraceMaxDepthOffFF" ;
                                    menuItem -label "enable Values" -c "raytraceMaxDepthOnFF" ;
                            floatField -w 150 -h 20 -v 1 -en false rtmdFF ;
                        setParent ..;
                        rowLayout
                        -numberOfColumns 2
                        -columnWidth2 45 120
                        -columnAlign2 "left" "left" ;
                            text -label "Pixel Samples" -w 120 -h 20;
                                popupMenu;
                                    menuItem -label "keep current Values" -c "PixelSamplesOff" ;
                                    menuItem -label "enable Values" -c "PixelSamplesOn" ;
                            floatFieldGrp -numberOfFields 2 -w 150 -h 20 -value1 1 -value2  1 -en false pSFF ;
                            ;
                        setParent ..;
                   
                    optionMenu -label "Pixel Filter" -width 240 -h 28 pfOM ;
                    menuItem -label  "keep current Settings" ;
                    menuItem -label  "box" ;
                    menuItem -label  "triangle" ;
                    menuItem -label  "gaussian" ;
                    menuItem -label  "catmull-rom" ;
                    menuItem -label  "bessel" ;
                    menuItem -label  "sinc" ;
                    menuItem -label  "mitchell" ;
                    menuItem -label  "zmin" ;
                    menuItem -label  "zmax" ;
                   
                    rowLayout
                        -numberOfColumns 2
                        -columnWidth2 45 120
                        -columnAlign2 "left" "left" ;
                            text -label "Filter Width" -w 120 -h 20;
                                popupMenu;
                                    menuItem -label "keep current Values" -c "FilterWidthsOff" ;
                                    menuItem -label "enable Values" -c "FilterWidthsOn" ;
                            floatFieldGrp -numberOfFields 2 -w 150 -h 20 -value1 4 -value2  4 -en false fWFF ;
                            ;
                        setParent ..;
           

            setParent ..;
            /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
            //MotionBlur FrameLayout
            ////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
           
           
            frameLayout -label "motion Blur" -collapsable true -cl true -borderStyle "etchedIn" -mw 30 -w  340 -bgc 0.24 0.24 0.24 ;
                        rowLayout
                        -numberOfColumns 3
                        -columnWidth3 35 30 120
                        -columnAlign3 "left" "left" "left" ;
                            text -label "Camera Blur Samples" -w 150 -h 20;
                                popupMenu;
                                    radioMenuItemCollection;
                                     menuItem -label "keep current Value"   -radioButton on -c "cameraBlurSamplesCBkcv" cbskcvMI ;
                                     menuItem -label "Off" -radioButton off -c "cameraBlurSamplesCBoff" cbsoffMI;
                                     menuItem -label "On"    -radioButton off -c "cameraBlurSamplesCBon" cbsonMI ;
                                     menuItem -label "On change Values"   -c "cameraBlurSamplesCBoncv" -radioButton off cbsoncvMI ;
                        checkBox -l "" -en false -bgc 0.23 0.23 0.23 cbCB;
                        intField  -w 150 -h 20 -v 2 -minValue 1 -maxValue 20 -en false cbsIF ;
                       
                        setParent ..;
                        rowLayout
                        -numberOfColumns 3
                        -columnWidth3 35 30 120
                        -columnAlign3 "left" "center" "left" ;
                            text -label "Transformation  Samples" -w 150 -h 20;
                                popupMenu;
                                radioMenuItemCollection;
                                     menuItem -label "keep current Value"   -radioButton on  -c "TransformationSampleskcv" tskcvMI;
                                     menuItem -label "Off" -radioButton off        -c"TransformationSamplesoff"         tsoffMI ;
                                     menuItem -label "On"    -radioButton off -c"TransformationSampleson" tsonMI ;
                                     menuItem -label "On change Values"    -radioButton off -c "TransformationSamplesoncv"  tsoncvMI ;
                        checkBox -l "" -en false -bgc 0.23 0.23 0.23  tbCB ;
                        intField  -w 150 -h 20 -v 2 -minValue 1 -maxValue 20 -en false tbsIF ;
                        setParent ..;
                        rowLayout
                        -numberOfColumns 3
                        -columnWidth3 35 30 120
                        -columnAlign3 "left" "center" "left" ;
                            text -label "Derformation Samples" -w 150 -h 20;
                                popupMenu;
                                    radioMenuItemCollection;
                                     menuItem -label "keep current Value"   -radioButton on  -c"deformationSampleskcv"   dskcvMI ;
                                     menuItem -label "Off" -radioButton off -c"deformationSamplesoff" dsoffMI ;
                                     menuItem -label "On"    -radioButton off  -c"deformationSampleson" dsonMI ;
                                     menuItem -label "On change Values"  -c"deformationSamplesoncv"  -radioButton off dsocvMI ;
                        checkBox -l "" -en false  -bgc 0.23 0.23 0.23 dsCB ;
                        intField  -w 150 -h 20 -v 2 -minValue 1 -maxValue 20 -en false dsIF ;
                        setParent ..;
                   
                    optionMenu -label "Motion Blur Position" -width 240 -h 28 mbpOM ;
                    menuItem -label  "keep current Settings" ;
                    menuItem -label  "centred on frame" ;
                    menuItem -label  "start on frame" ;
                    menuItem -label  "end on frame" ;


           

            setParent ..;
               
            //DisplayOptionsy FrameLayout    
                  
            frameLayout -label "Displays " -collapsable true -cl true -borderStyle "etchedIn" -mw 30 -w  340 -bgc 0.24 0.24 0.24 ;
                frameLayout -label "framebuffer" -collapsable true -borderStyle "etchedIn" -mw 30 -w  300;
               
                        optionMenu -label "displayDriver" -width 240 saveAsOM;
                            menuItem -label "keep current displayDriver";
                            menuItem -label "framebuffer";
                            menuItem -label "idisplay";
                            menuItem -label "maya_render_view";
                            menuItem -label "tiff";
                            menuItem -label "iff";
                            menuItem -label "exr";
                            menuItem -label "cineon";
                            menuItem -label "zfile";
                            menuItem -label "bmp";
                            menuItem -label "eps";
                            menuItem -label "psd";
                            menuItem -label "radiance";
                            menuItem -label "null";
                            menuItem -label "shadowmap";
                            menuItem -label "texture";
                            menuItem -label "dsm";
                        optionMenu -label "bitDepth      "  -width 240 bitDepthOM2;
                            menuItem -label "keep current bitDepth";
                            menuItem -label "8 bit integer";
                            menuItem -label "16 bit integer";
                            menuItem -label "32 bit float";
                           
       
               
                setParent ..;    
                frameLayout -label "Gain & Gamma" -collapsable true -borderStyle "etchedIn" -mw 30 -w 300 ;
                    checkBox  -v true -height 28 -label "keep current Values" -width 300 -ofc "OnGGcB" -onc "OffGGcB" KCVCB ;
                     rowLayout
                        -numberOfColumns 2
                        -columnWidth2 45 120
                        -columnAlign2 "center" "center" ;
                            text -label "Gain:" -w 40 -h 20;
                            floatField -w 100 -h 20 -v 1 -en false gainFF ;
                     setParent ..;    
                   
                     rowLayout
                        -numberOfColumns 2
                        -columnWidth2 45 120
                        -columnAlign2 "center" "center" ;
                            text -label "Gamma:" -w 40 -h 20;
                            floatField -w 100 -h 20 -v 1 -en false gammaFF ;
                     setParent ..;    
                setParent ..;    
                frameLayout -label "alpha Attrs" -collapsable true -borderStyle "etchedIn" -mw 30 -w 300;
                    checkBox -h 25 -l "Keep current Alpha settings" -w 300 -v true -offCommand "OnAlphaValues" -onCommand "OffAlphaValues" kCAVCB  ;
                    separator -height 4 -width 288;
                    checkBox -height 28 -label "Use Matte Alpha" -width 300 -en false UMACB ;
                    checkBox -height 28 -label "Exclusiv Output" -width 300 -en false EOCB;
                    checkBox -height 28 -label "Associate Alpha" -width 300 -en false AACB;
                    checkBox -height 28 -label "Compute Alpha" -width 300 -en false CACB;
                setParent ..;
            setParent ..;
            frameLayout -label "Global Illumination " -collapsable true -cl true -borderStyle "etchedIn" -mw 30 -w  340 -bgc 0.24 0.24 0.24 ;
                optionMenu -label "Effect" -width 240 -h 28 giOM ;
                menuItem -label  "keep current Settings" ;
                menuItem -label  "None" ;
                menuItem -label  "Occlusion" ;
                menuItem -label  "Fast Image Base Lighting" ;
                menuItem -label  "Full Global Illumination" ;
               
           
               
            setParent ..;    
            button -height 18 -label "reset all Attr" -c "rf_resetAll" -width 340 ;
            separator -height 17 -width 340 ;
            button -height 28 -label "SetAttrs" -c "setAttrs" -width 340;
            button -height 28 -label "refresh UI selected passes" -c " refreshUI" -width 340;
        setParent ..;
    showWindow;
    //Set TextScrolList
    for( $i=0; $i<$delightPassesIndex; ++$i )
        {
                textScrollList -e -append $delightPasses[$i] passesTSL ;       
        } 
}

}



// CODE PROCS 




////////////////////////////////////////////////////////////////////
///UI procs
///////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////
//ResetAll
/////////////////////////////////////////////////////////////////
global proc rf_resetAll(){
    rf_m3dl_UI ;
    }
//////////////////////////////////////////////////////////////////
//Display
//////////////////////////////////////////////////////////////////
global proc OnGGcB (){
    floatField -e -en true gainFF ;    
    floatField -e -en true gammaFF ;
    }
global proc OffGGcB (){
    floatField -e -en false gainFF ;    
    floatField -e -en false gammaFF ;
    }
global proc OnAlphaValues(){
    checkBox -e -en true UMACB ;
    checkBox -e -en true EOCB ;
    checkBox -e -en true AACB ;
    checkBox -e -en true CACB ;
}

global proc OffAlphaValues(){
    checkBox -e -en false UMACB ;
    checkBox -e -en false EOCB ;
    checkBox -e -en false AACB ;
    checkBox -e -en false CACB ;
}
////////////////////////////////////////////////////////////////////
//Refresh
////////////////////////////////////////////////////////////////////
global proc refreshTL (){

    textScrollList -e -ra passesTSL ;
   
    string $procDelightPasses[] = `ls -type "delightRenderPass" `;
    int $procDelightPassesIndex =` size( $procDelightPasses)` ;
   
    for( $i=0; $i<$procDelightPassesIndex; ++$i )
        {
                textScrollList -e -append $procDelightPasses[$i] passesTSL ;        
        }  
}

global proc refreshUI(){
    string $selectedPasses[] =`textScrollList -q -selectItem passesTSL` ;
    for ( $currentPass in $selectedPasses){
        AE_DRP_update $currentPass ;
    }
}
/////////////////////////////////////////////////////////////////////////////////////////
//is Equal Proc
////////////////////////////////////////////////////////////////////////////////////////
 global proc int isEqual( vector $v1, vector $v2 )
 {
   int $isEqual = 0;
   vector  $tol = <<0.01, 0.01, 0.01>> ;
   if( abs($v1-$v2) < $tol )
      $isEqual = 1;
   return $isEqual;
 }
 

////////////////////////////////////////////////////////////////////
//MotionBlur
///////////////////////////////////////////////////////////////////

////////CameraBlur////////////////////////////////////////////////

global proc cameraBlurSamplesCBkcv(){
    checkBox -e -v false cbCB ;
    checkBox -e -bgc 0.23 0.23 0.23 cbCB ;
    intField -e -en false cbsIF ;
    }

global proc cameraBlurSamplesCBon (){
    checkBox -e -v true cbCB ;
    checkBox -e -bgc 0.1 0.5 0.1 cbCB ;
    intField -e -en false cbsIF ;
    }
   
global proc cameraBlurSamplesCBoff (){
    checkBox -e -v false cbCB ;
    checkBox -e -bgc 0.5 0.1 0.1 cbCB ;
    intField -e -en false cbsIF ;
    }
   
global proc cameraBlurSamplesCBoncv (){
    checkBox -e -v true cbCB ;
    checkBox -e -bgc 0.1 0.1 0.5 cbCB ;
    intField -e -en true cbsIF ;
    }  
////////TransformationBlur//////////////////////////////////
global proc TransformationSampleskcv () {
    checkBox -e -v false tbCB ;
    checkBox -e -bgc 0.23 0.23 0.23 tbCB ;
    intField -e -en false tbsIF ;
    }
        
global proc TransformationSampleson(){
    checkBox -e -v true tbCB ;
    checkBox -e -bgc 0.1 0.5 0.1  tbCB ;
    intField -e -en false tbsIF ;
    }
   
global proc TransformationSamplesoff (){
    checkBox -e -v false tbCB ;
    checkBox -e -bgc 0.5 0.1 0.1 tbCB ;
    intField -e -en false tbsIF ;
    }
   
global proc TransformationSamplesoncv(){
    checkBox -e -v true tbCB ;
    checkBox -e -bgc 0.1 0.1 0.5 tbCB ;
    intField -e -en true tbsIF ;
    }
   
       
/////////DeformationBlur//////////////////////////////////////////
global proc deformationSampleskcv (){
    checkBox -e -v false dsCB ;
    checkBox -e -bgc 0.23 0.23 0.23 dsCB ;
    intField -e -en false dsIF ;
    }
   

global proc deformationSampleson(){
    checkBox -e -v true dsCB ;
    checkBox -e -bgc 0.1 0.5 0.1 dsCB ;
    intField -e -en false dsIF ;
    }
   
global proc deformationSamplesoff(){
    checkBox -e -v false dsCB ;
    checkBox -e -bgc 0.5 0.1 0.1 dsCB ;
    intField -e -en false dsIF ;
    }
   
global proc deformationSamplesoncv() {
    checkBox -e -v true dsCB ;
    checkBox -e -bgc 0.1 0.1 0.5 dsCB ;
    intField -e -en true dsIF ;
    }   

///////////////////////////////////////////////////////////////////
//Camera
///////////////////////////////////////////////////////////////////
global proc aniFrameONproc (){
    text -e -en true startFrameTXT ;
    intField -e -en true startFrameIF ;
    text -e -en true endFrameTXT ;
    intField -e -en true endFrameIF ;
    }

global proc aniFrameOFFproc (){
    text -e -en false startFrameTXT ;
    intField -e -en false startFrameIF ;
    text -e -en false endFrameTXT ;
    intField -e -en false endFrameIF ;
    }
//////////////////////////////////////////////////////////////////
// Quality    
/////////////////////////////////////////////////////////////////
global proc shadingRateOffFF(){
    floatField -e -en false srFF ;
    }
proc shadingRateOnFF(){
    floatField -e -en true srFF ;
    }    
global proc raytraceMaxDepthOffFF(){
    floatField -e -en false rtmdFF ;
    }
global proc raytraceMaxDepthOnFF(){
    floatField -e -en true rtmdFF ;
    }
   
global proc PixelSamplesOn(){    
    floatFieldGrp -e -en true pSFF ;

    }
   
global proc PixelSamplesOff(){    
    floatFieldGrp -e -en false pSFF ;

    }
   
global proc FilterWidthsOff(){    
    floatFieldGrp -e -en false fWFF ;

    }
   
   
global proc FilterWidthsOn(){    
    floatFieldGrp -e -en true fWFF ;

    }
/////////////////////////////////////////////////////////////////////////////////
// Proc
/////////////////////////////////////////////////////////////////////////////////
global proc setAttrs(){
    vector $grey = << 0.23, 0.23, 0.23 >> ;
    vector $red = << 0.5, 0.1, 0.1 >> ;
    vector $green = << 0.1, 0.5, 0.1 >> ;
    vector $blue = << 0.1, 0.1, 0.5 >> ;

   
    string $selectedPasses[] =`textScrollList -q -selectItem passesTSL` ; 

    //getCamera
    string $renderCam =`optionMenu -q -v camOM` ;
    //get Animation
    string $AnimationSet =`optionMenu -q -v animOM` ;
    //get checkBox frameRate
    int $FrameRangeCB = ` checkBox -q -v snFRCB ` ;
    //get FrameRange
    int $startFrameVal =`intField -q -v startFrameIF` ;
    int $endFrameVal =`intField -q -v endFrameIF` ;
    //get useImageShaders
    string $useImageShadersVal =`optionMenu -q -v uISOM` ;
   
    //get PixelFilter
    string $pixelFilter =`optionMenu -q -v  pfOM` ;
   
    ////////////////////////////
    //Quality
    ////////////////////////////
    //ShadingRate

    int $srFF =`floatField -q -en srFF`;
    float $srFFV =`floatField -q -v srFF `;

    // RayTrace maxDepth

    int $rtmdFF =`floatField -q -en rtmdFF`;
    float $rtmdFFV =`floatField -q -v rtmdFF`;

    //PixelSamples

    int $pSFF =`floatFieldGrp -q -en pSFF`;
    float $pSFFV1 = `floatFieldGrp -q -value1 pSFF`;
    float $pSFFV2 = `floatFieldGrp -q -value2 pSFF`;

   


    //FilterWith
    int $fWFF =`floatFieldGrp -q -en  fWFF`;
    float $fWFFV1 = `floatFieldGrp -q -value1 fWFF`;
    float $fWFFV2 = `floatFieldGrp -q -value2 fWFF`;
   
    //MotionBlur
   
    //get BackGroundColor
    vector $TBCBC = `checkBox -q -bgc tbCB` ;
    vector $cbCB =`checkBox -q -bgc cbCB`;
    vector $dsCb =`checkBox -q -bgc dsCB `;
   
    //get Int Samples Values
   
    int $TSV =`intField -q -v tbsIF` ;
    int $CBSV = `intField -q -v cbsIF `;
    int $DSV = `intField -q -v dsIF `;
   
   
   
    //getAlphaSettings
   
    int $cB1 = `checkBox -q -v UMACB` ;
    int $cB2 = `checkBox -q -v EOCB` ;
    int $cB3 = `checkBox -q -v AACB` ;
    int $cB4 = `checkBox -q -v CACB` ;

    //getgamma and Gain Values
    float $gainVal =`floatField -q -v gainFF` ;
    float $gammaVal =`floatField -q -v gammaFF` ;
   
    //get Framebuffer values
    string $displayDriverVal =`optionMenu -q  -v saveAsOM` ;
    string $bitDepthVal =`optionMenu -q -v bitDepthOM2 ` ;
   
    //get RenderMode value
    string $renderModeVal =`optionMenu -q  -v  rmOM` ;
   
    //get Global Illumination
    string $globalIlluminationVal =`optionMenu -q -v giOM` ;

     int $passesIndex =size($selectedPasses);
    for( $i=0; $i<$passesIndex; ++$i )
    {
        int $delightDisplayIndex[] = `DRP_getDisplayIndices($selectedPasses[$i])`;
        ////////////////////////////////////////////////////////////////////////////////////////
        //Camera
        ///////////////////////////////////////////////////////////////////////////////////////
        if ($renderCam != "keep current Camera"){
            string $Camconnection[] =`listConnections -s true -d false ( $selectedPasses[$i] + ".camera") `;
        
            string $camname =  ( $Camconnection[0] + "Shape" ) ;
            //int $testCamCon =`isConnected ($renderCam + ".usedBy3dfm") ( $selectedPasses[$i] + ".camera")` ;
            if ($camname != $renderCam){
                //connectAttr -f ($renderCam + ".usedBy3dfm") ( $selectedPasses[$i] + ".camera") ;
                string $camera_attr =$selectedPasses[$i] + ".camera";

                  DL_disconnectNode($camera_attr);
                DL_connectNodeToMessagePlug( $renderCam, $camera_attr);   
       
            }
            
            
                print "\n" ;
                print "camera is set to " ;
                print $renderCam  ;
                print "\n" ;

        }

        else {
            print "\n" ;
            print " unchanged camera " ;
            print "\n" ;
            }
            ;
        //Animation    
        switch($AnimationSet)
            {
                case "keep current Settings" :
                print "\n" ;
                print "Animation keeps current Value" ;
                print "\n" ;
                break ;
                
                case "Animation On" :
                print "\n" ;
                print "Animation set to ON" ;
                print "\n" ;
                setAttr ($selectedPasses[$i] +".animation") 1 ;
                break ;
                
                case "Animation Off" :
                print "\n" ;
                print "Animation set to ON" ;
                print "\n" ;
                setAttr ($selectedPasses[$i] +".animation") 0 ;
                break ;
                
                
                }
        if     ($FrameRangeCB != 0){
            setAttr ($selectedPasses[$i] +".startFrame") $startFrameVal ;
            setAttr ($selectedPasses[$i] +".endFrame") $endFrameVal ;    
            }
        else{
            print "\n" ;
            print "animation frameRange keeps current settings" ;
            print "\n" ;
            }
        //imageShader    
        switch( $useImageShadersVal)
            {
                case "keep current Settings" :
                print "\n" ;
                print "ImageShader keeps current Value" ;
                print "\n" ;
                break ;
                
                case "on" :
                print "\n" ;
                setAttr ($selectedPasses[$i] +".useImagerShaders") 1 ;
                print "\n" ;
                break ;
                
                case "off" :
                print "\n" ;
                setAttr ($selectedPasses[$i] +".useImagerShaders") 0 ;
                print "\n" ;
                break ;
            }
            
            //RenderMode
        switch( $renderModeVal)
            {
                case "keep current Settings" :
                print "\n" ;
                print "RenderMode keeps current Value" ;
                print "\n" ;
                break ;
                
                case "Render" :
                setAttr ($selectedPasses[$i] +".renderMode") 0 ;
                print "\n" ;
                print "renderMode is set to Render" ;
                print "\n" ;;
                break ;
                
                case "Save RIB" :
                setAttr ($selectedPasses[$i] +".renderMode") 1 ;
                print "\n" ;
                print "renderMode is set to Save RIB" ;
                print "\n" ;
                break ;
                
                case "RIB Archive" :
                setAttr ($selectedPasses[$i] +".renderMode") 2 ;
                print "\n" ;
                print "renderMode is set to RIB Archive " ;
                print "\n" ;
                break ;
                
                case "Background Render" :
                setAttr ($selectedPasses[$i] +".renderMode") 3 ;
                print "\n" ;
                print "renderMode is set to Background Render" ;
                print "\n" ;
                break ;
            }
        
        //Quality
        //ShadingRate
        if ($srFF == 1){
               setAttr ($selectedPasses[$i] +".shadingRate") $srFFV ;
   
                }
            else{
                    print "shadingRate keeps it Value" ;
                }
   
        //raytraceMaxDepth
            if ($rtmdFF == 1){
                   setAttr ($selectedPasses[$i] +".raytraceMaxDepth") $rtmdFFV ;
   
                    }
            else{
                    print "raytraceMaxDepth keeps it Value" ;
                }
        
        //PixelSamples
            if ($pSFF == 1){
                   setAttr ($selectedPasses[$i] +".pixelSamplesX") $pSFFV1 ;
                   setAttr  ($selectedPasses[$i] +".pixelSamplesY") $pSFFV2 ;
                }
            else{
                    print "pixel Samples keep their Values" ;
                   }

        
        
        //PixelFilter
            switch( $pixelFilter)
            {
                case "keep current Settings" :
                print "\n" ;
                print "pixelFilter keeps current Value" ;
                print "\n" ;
                break ;
                
                case "box" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 0 ;
                print "\n" ;
                print "pixelFilter is set to box" ;
                print "\n" ;;
                break ;
                
                case "triangle" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 1 ;
                print "\n" ;
                print " pixelFilter is set to triangle " ;
                print "\n" ;
                break ;
                
                case "gaussian" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 2 ;
                print "\n" ;
                print "pixelfilter is set to gaussian " ;
                print "\n" ;
                break ;
                
                case "catmull-rom" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 3 ;
                print "\n" ;
                print "pixelFilter is set to catmull-rom" ;
                print "\n" ;
                break ;
                
                case "bessel" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 4 ;
                print "\n" ;
                print "pixelFilter is set to bessel" ;
                print "\n" ;
                break ;
                
                case "sinc" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 5 ;
                print "\n" ;
                print "pixelFilter is set to sinc" ;
                print "\n" ;
                break ;
                
                case "mitchell" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 6 ;
                print "\n" ;
                print "pixelFilter is set to mitchell" ;
                print "\n" ;
                break ;
                
                case "zmin" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 7 ;
                print "\n" ;
                print "pixelFilter is set to zmin" ;
                print "\n" ;
                break ;
                
                case "zmaxn" :
                setAttr ($selectedPasses[$i] +".pixelFilter") 8 ;
                print "\n" ;
                print "pixelFilter is set to zmax" ;
                print "\n" ;
                break ;
                
                
                
            }
            //FilterWidth
            if ($fWFF == 1){
                   setAttr ($selectedPasses[$i] +".filterWidthX") $fWFFV1 ;
                   setAttr  ($selectedPasses[$i] +".filterWidthY") $fWFFV2 ;
                    }
            else{
                    print "FilterWidth keeps it Value" ;
                }

            //////////////////////////////////////////////////////////////////////////////////////////
            ///////////////Motion Blur
            //////////////////////////////////////////////////////////////////////////////////////////
            //TransFormationBlur
             
             if ( isEqual($TBCBC,$grey) == 1){
                 print " Transformation Samples keeps value" ;
                 }
                 
             if ( isEqual($TBCBC,$red) == 1){
                 print "Transformation Samples is turned off" ;
                 setAttr ($selectedPasses[$i] + ".transformationBlur") 0;
                 }
                
             if ( isEqual($TBCBC,$green) == 1){
                 print "Transformation Samples is turned on" ;
                 setAttr ($selectedPasses[$i] +".transformationBlur") 1;
                 }
             if ( isEqual($TBCBC,$blue) == 1){
                 print "Transformation Samples is turned on and takes the new Value" ;
                 setAttr ($selectedPasses[$i] +".transformationBlur") 1;
                 setAttr ($selectedPasses[$i] +".transformationSamples") $TSV ;
                  }
              
             //Camera Blur Samples
            
             if ( isEqual($cbCB,$grey) == 1){
                 print " camera Blur Samples keeps value" ;
                 }
                 
             if ( isEqual($cbCB,$red) == 1){
                 print " camera Blur Samples is turned off" ;
                 setAttr ($selectedPasses[$i] + ".cameraBlur") 0;
                 }
                
             if ( isEqual($cbCB,$green) == 1){
                 print "camera Blur Samples is turned on" ;
                 setAttr ($selectedPasses[$i] +".cameraBlur") 1;
                 }
             if ( isEqual($cbCB,$blue) == 1){
                 print "camera Blur Samples is turned on and takes the new Value" ;
                 setAttr ($selectedPasses[$i] +".cameraBlur") 1;
                 setAttr ($selectedPasses[$i] +".cameraBlurSamples")  $CBSV ;
                  }
 
            //DeformationBlur
            
             if ( isEqual($dsCb,$grey) == 1){
                 print " Deformation Samples keeps value" ;
                 }
                 
             if ( isEqual($dsCb,$red) == 1){
                 print " Deformation Samples is turned off" ;
                 setAttr ($selectedPasses[$i] + ".deformationBlur") 0;
                 }
                
             if ( isEqual($dsCb,$green) == 1){
                 print "Deformation Samples is turned on" ;
                 setAttr ($selectedPasses[$i] +".deformationBlur") 1;
                 }
             if ( isEqual($dsCb,$blue) == 1){
                 print "Deformation Samples is turned on and takes the new Value" ;
                 setAttr ($selectedPasses[$i] +".deformationBlur") 1;
                 setAttr ($selectedPasses[$i] +".deformationSamples")  $DSV ;
                  }







            //////////////////////////////////////////////////////////////////////////////////////////
            ///////////////Global Illumination
            //////////////////////////////////////////////////////////////////////////////////////////
            switch( $globalIlluminationVal)
            {
                case "keep current Settings" :
                print "\n" ;
                print "Global Illumination keeps current Value " ;
                print "\n" ;
                break ;
                
                case "None":
                print "\n" ;
                setAttr ($selectedPasses[$i] +".giEffect") 0 ;
                print "\n" ;
                break ;
                
                case "Occlusion" :
                print "\n" ;
                setAttr ($selectedPasses[$i] +".giEffect") 1 ;
                print "\n" ;
                break ;
                
                case "Fast Image Base Lighting" :
                print "\n" ;
                setAttr ($selectedPasses[$i] +".giEffect") 2 ;
                print "\n" ;
                break ;
                
                case "Full Global Illumination" :
                print "\n" ;
                setAttr ($selectedPasses[$i] +".giEffect") 3 ;
                print "\n" ;
                break ;
            }
                



           for ($current in $delightDisplayIndex)
        {
            ////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
            ///ALPHA VALUES
            ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
            
            if (`checkBox -q -v kCAVCB` == 0){
                   string $displayMattes =("setAttr " + $selectedPasses[$i] + ".displayMattes"+"[" +$current + "] " + $cB1);
                eval  $displayMattes ;
                    
                string $displayExclusives =("setAttr " + $selectedPasses[$i] + ".displayExclusives"+"[" +$current + "] " + $cB2);
                eval  $displayExclusives ;

                string $displayAssociateAlphas =("setAttr " + $selectedPasses[$i] + ".displayAssociateAlphas"+"[" +$current + "] " + $cB3);
                eval  $displayAssociateAlphas ;
            
                string $displayComputeAlphas =("setAttr " + $selectedPasses[$i] + ".displayComputeAlphas"+"[" +$current + "] " + $cB4);
                eval  $displayComputeAlphas ;
            }
            else{
                print "\n" ;
                print "AlphaAttrs keep their current Values for " ;
                print $selectedPasses[$i] ;
                print "\n" ;    
            }
            ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
            ///GAIN $ GAMMA
            ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
            if (`checkBox -q -v  KCVCB` == 0){
            
                string $gain =("setAttr " + $selectedPasses[$i] + ".displayGains"+"[" +$current + "] " + $gainVal);
                eval $gain ;
            
                string $gamma =("setAttr " + $selectedPasses[$i] + ".displayGammas"+"[" +$current + "] " + $gammaVal);
                eval $gamma ;
                
                }
            else
                {
                print "\n" ;
                print "Gamma and Gain keep their current Values for " ;
                print $selectedPasses[$i] ;
                print "\n" ;    
                }  
            //////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
            //FrameBuffer Values
            /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
            if ( $displayDriverVal != "keep current displayDriver" ){
                
                string $displayDrivers =("setAttr " + $selectedPasses[$i] + ".displayDrivers"+"[" +$current + "] " +"-type" +("\"" + "string" +"\"" ) + $displayDriverVal);
                eval $displayDrivers ;
                }
            else
            {
                print "\n" ;
                print "DisplayDriver keep its current Value for " ;
                print $selectedPasses[$i] ;
                print "\n" ;
               }
            
            switch($bitDepthVal)
            {
                case "keep current bitDepth" :
                print "\n" ;
                print "bitDepth keeps current Value" ;
                print "\n" ;
                break ;
                
                case "8 bit integer" :
                print "\n" ;
                print "bitDepth set to 8 bit int" ;
                print "\n" ;
                DRP_setDisplayQuantizeAttrs($selectedPasses[$i], $current, 0, 255, 0, 255, 0.5);
                break ;
                
                case "16 bit integer" :
                print "\n" ;
                print "bitDepth set to 16 bit int" ;
                print "\n" ;
                DRP_setDisplayQuantizeAttrs($selectedPasses[$i], $current, 0, 65535, 0, 65535, 0.5);
                break ;
                
                case "32 bit float" :
                print "\n" ;
                print "bitDepth set to 32 bit float" ;
                print "\n" ;
                DRP_setDisplayQuantizeAttrs($selectedPasses[$i], $current, 0, 0, 0, 0, 0);
                break ;
                }
            
            
   
   
   
         

        }
    }

}